eraser.java-common-conventions.gradle

plugins {
  id 'java'
  id 'idea'
  id 'com.github.ben-manes.versions'
  id 'jacoco'
}

repositories {
  mavenCentral()
}

java {
  toolchain {
    languageVersion = JavaLanguageVersion.of(11)
  }
}

dependencies {
  implementation group: 'org.apache.logging.log4j', name: 'log4j-api', version: "${log4j_version}"
  implementation group: 'org.apache.logging.log4j', name: 'log4j-core', version: "${log4j_version}"
  testImplementation group: 'org.junit.jupiter', name: 'junit-jupiter-api', version: "${jupiter_version}"
  testImplementation group: 'org.assertj', name: 'assertj-core', version: '3.18.1'
  testRuntimeOnly group: 'org.junit.jupiter', name: 'junit-jupiter-engine', version: "${jupiter_version}"
}

tasks.named('test') {
  useJUnitPlatform {
    excludeTags 'mqtt | influx'
  }
}

tasks.withType(JavaCompile) {
    options.deprecation = true
}

task allTests(type: Test, dependsOn: testClasses) {
  description = 'Run every test'
  group = 'verification'

  useJUnitPlatform {
  }
}

// extension for all Test tasks similar to https://stackoverflow.com/a/57330075/2493208
jacocoTestReport {
    executionData tasks.withType(Test).findAll { it.state.executed }
    getExecutionData().setFrom(fileTree(buildDir).include("/jacoco/*.exec"))

    reports {
        xml.enabled true
        xml.destination(file("${jacoco.reportsDir}/all-tests/jacocoAllTestReport.xml"))
        html.enabled false
    }
}

tasks.withType(Test) {
    finalizedBy jacocoTestReport
}