Skip to content
Snippets Groups Projects
Select Git revision
  • master default protected
  • 20-poc-use-tinytemplate-as-template-engine
  • dev/rene
  • feature/submodule
  • feature/relast
5 results

build.gradle

Blame
    • build.gradle 5.00 KiB 
    apply plugin: 'jastadd'
apply plugin: 'application'

sourceCompatibility = 1.8

mainClassName = 'org.jastadd.ros2rag.compiler.Compiler'

repositories {
    jcenter()
}

buildscript {
    repositories.jcenter()
    dependencies {
        classpath 'org.jastadd:jastaddgradle:1.13.3'
    }
}

dependencies {
    implementation 'com.fasterxml.jackson.core:jackson-core:2.9.8'
    implementation 'com.fasterxml.jackson.core:jackson-databind:2.9.8'
//    api 'org.jastadd:jastadd:2.3.4'
    runtime 'org.jastadd:jastadd:2.3.4'
    api group: 'net.sf.beaver', name: 'beaver-rt', version: '0.9.11'
}

sourceSets {
    main {
        java.srcDir "src/gen/java"
    }
}

test {
    useJUnitPlatform()

    maxHeapSize = '1G'
}

jar {
    manifest {
        attributes "Main-Class": 'org.jastadd.ros2rag.compiler.Compiler'
    }

    from {
        configurations.compile.collect { it.isDirectory() ? it : zipTree(it) }
    }
}

task relast(type: JavaExec) {
    group = 'Build'
    main = "-jar"

    doFirst {
        delete "src/gen/jastadd/*.ast"
        delete "src/gen/jastadd/Ros2Rag.jadd"
        delete "src/gen/jastadd/Ros2RagRefResolver.jadd"
        delete "src/gen/jastadd/Ros2RagResolverStubs.jrag"
        mkdir  "src/gen/jastadd/"
    }

    args = [
            "../libs/relast.jar",
            "../relast.preprocessor/src/main/jastadd/RelAst.relast",
            "./src/main/jastadd/Ros2Rag.relast",
            "--listClass=java.util.ArrayList",
            "--jastAddList=JastAddList",
            "--useJastAddNames",
            "--file",
            "--resolverHelper",
            "--grammarName=./src/gen/jastadd/Ros2Rag"
        ]

    inputs.files file("../libs/relast.jar"),
            file("../relast.preprocessor/src/main/jastadd/RelAST.relast"),
            file("src/main/jastadd/Ros2Rag.relast")
    outputs.files file("./src/gen/jastadd/Ros2Rag.ast"),
            file("src/gen/jastadd/Ros2Rag.jadd"),
            file("src/gen/jastadd/Ros2RagRefResolver.jadd"),
            file('src/gen/jastadd/Ros2RagResolverStubs.jrag')
}

jastadd {
    configureModuleBuild()
    modules {
        //noinspection GroovyAssignabilityCheck
        module("Ros2Rag") {

            java {
                basedir ".."
                include "relast.preprocessor/main/**/*.java"
                include "relast.preprocessor/gen/**/*.java"
                include "ros2rag.base/src/main/**/*.java"
                include "ros2rag.base/src/gen/**/*.java"
            }

            jastadd {
                basedir ".."
                include "relast.preprocessor/src/main/jastadd/**/*.ast"
                include "relast.preprocessor/src/main/jastadd/**/*.jadd"
                include "relast.preprocessor/src/main/jastadd/**/*.jrag"
                include "ros2rag.base/src/main/jastadd/**/*.ast"
                include "ros2rag.base/src/main/jastadd/**/*.jadd"
                include "ros2rag.base/src/main/jastadd/**/*.jrag"
                include "ros2rag.base/src/gen/jastadd/**/*.ast"
                include "ros2rag.base/src/gen/jastadd/**/*.jadd"
                include "ros2rag.base/src/gen/jastadd/**/*.jrag"
            }

            scanner {
                basedir ".."
                include "ros2rag.base/src/main/jastadd/scanner/Header.flex",               [-5]
                include "relast.preprocessor/src/main/jastadd/scanner/Preamble.flex",      [-4]
                include "relast.preprocessor/src/main/jastadd/scanner/Macros.flex",        [-3]
                include "ros2rag.base/src/main/jastadd/scanner/Macros.flex",               [-3]
                include "relast.preprocessor/src/main/jastadd/scanner/RulesPreamble.flex", [-2]
                include "ros2rag.base/src/main/jastadd/scanner/MappingContent.flex",       [-1]
                include "ros2rag.base/src/main/jastadd/scanner/Keywords.flex"
                include "relast.preprocessor/src/main/jastadd/scanner/Keywords.flex"
                include "relast.preprocessor/src/main/jastadd/scanner/Symbols.flex",        [1]
                include "relast.preprocessor/src/main/jastadd/scanner/RulesPostamble.flex", [2]
            }

            parser {
                basedir ".."
                include "ros2rag.base/src/main/jastadd/parser/Preamble.parser"
                include "ros2rag.base/src/main/jastadd/parser/Ros2Rag.parser"
                include "relast.preprocessor/src/main/jastadd/parser/RelAst.parser"
            }
        }
    }

    cleanGen.doFirst {
        delete "src/gen/java/org"
        delete "src/gen-res/BuildInfo.properties"
    }

    preprocessParser.doFirst {

        args += ["--no-beaver-symbol"]

        }

    module = "Ros2Rag"

    astPackage = 'org.jastadd.ros2rag.ast'

    parser.name = 'Ros2RagParser'

    genDir = 'src/gen/java'

    buildInfoDir = 'src/gen-res'

    scanner.genDir = "src/gen/java/org/jastadd/ros2rag/scanner"
    parser.genDir = "src/gen/java/org/jastadd/ros2rag/parser"

    jastaddOptions = ["--lineColumnNumbers", "--List=JastAddList", "--safeLazy", "--visitCheck=true", "--rewrite=cnta", "--cache=all"]
}

generateAst.dependsOn relast