build.gradle

plugins {
    id 'java-library'
    id 'application'
    id 'org.jastadd'
    id 'java'
    id 'idea'
    id 'java-test-fixtures'
}

ext {
    mainClassName = 'org.jastadd.relast.compiler.RelastSourceToSourceCompiler'
}

// set the main class name for `gradle run`
application.mainClassName = "${mainClassName}"

sourceCompatibility = 1.8
targetCompatibility = 1.8

repositories {
    mavenCentral()
}

sourceSets {
    model {
        java {
            srcDir "src/gen/java"
        }
    }
}

task modelJar(type: Jar) {
    group = "build"
    archiveBaseName = 'model'
    archiveVersion = ''
    from sourceSets.model.output
}

artifacts {
    archives modelJar
}

dependencies {

    modelImplementation group: 'org.jastadd', name: 'jastadd', version: '2.3.4'
    modelImplementation group: 'net.sf.beaver', name: 'beaver-rt', version: '0.9.11'

    implementation files(modelJar.archiveFile.get())
    api group: 'org.jastadd', name: 'jastadd', version: '2.3.4'
    api group: 'net.sf.beaver', name: 'beaver-rt', version: '0.9.11'
    implementation group: 'com.github.jknack', name: 'handlebars', version: '4.2.0'
    implementation group: 'org.yaml', name: 'snakeyaml', version: '1.27'

    // test
    testRuntimeClasspath files(modelJar.archiveFile.get())

    // test fixtures
    testFixturesApi group: 'org.slf4j', name: 'slf4j-jdk14', version: '1.7.30'
    testFixturesApi group: 'org.junit.jupiter', name: 'junit-jupiter-engine', version: '5.7.0'
    testFixturesApi group: 'org.junit.jupiter', name: 'junit-jupiter-api', version: '5.7.0'
    testFixturesApi group: 'org.assertj', name: 'assertj-core', version: '3.18.0'
    testFixturesApi group: 'com.fasterxml.jackson.core', name: 'jackson-databind', version: '2.12.0-rc1'
    testFixturesApi group: 'com.fasterxml.jackson.dataformat', name: 'jackson-dataformat-yaml', version: '2.12.0-rc1'
    testFixturesApi group: 'commons-io', name: 'commons-io', version: '2.8.0'
}

def versionFile = 'src/main/resources/preprocessor.properties'
def versionProps = new Properties()

try {
    file(versionFile).withInputStream { stream -> versionProps.load(stream) }
    version = versionProps['version']
} catch (e) {
    // this happens, if either the properties file is not present, or cannot be read from
    throw new GradleException("File ${versionFile} not found or unreadable. Aborting.", e)
}

jar {
    manifest {
        attributes "Main-Class": "${mainClassName}"
    }

    from {
        configurations.runtimeClasspath.collect { it.isDirectory() ? it : zipTree(it) }
    }
}

test {
    useJUnitPlatform()

    maxHeapSize = '1G'
}

// Input and output files for relast
def relastInputFiles = [
        "src/main/jastadd/RelAst.relast",
        "src/main/jastadd/mustache/Mustache.relast"
]
def relastOutputFiles = [
        "src/gen/jastadd/RelAst.ast",
        "src/gen/jastadd/RelAst.jadd",
        "src/gen/jastadd/RelAstRefResolver.jadd",
        "src/gen/jastadd/RelAstResolverStubs.jrag"
]

task relast(type: JavaExec) {
    classpath = files("libs/relast.jar")
    group = 'Build'

    doFirst {
        delete relastOutputFiles
        mkdir "src/gen/jastadd/"
    }

    args = [
            "--listClass=java.util.ArrayList",
            "--jastAddList=JastAddList",
            "--useJastAddNames",
            "--file",
            "--resolverHelper",
            "--grammarName=./src/gen/jastadd/RelAst"
    ] + relastInputFiles

    inputs.files relastInputFiles
    outputs.files relastOutputFiles
}

jastadd {
    configureModuleBuild()
    modules {
        //noinspection GroovyAssignabilityCheck
        module("Preprocessor") {

            jastadd {
                include "src/main/jastadd/**/*.ast"
                include "src/main/jastadd/**/*.jadd"
                include "src/main/jastadd/**/*.jrag"
                include "src/gen/jastadd/**/*.ast"
                include "src/gen/jastadd/**/*.jadd"
                include "src/gen/jastadd/**/*.jrag"
            }

            scanner {
                include "src/main/jastadd/scanner/Header.flex",        [-4]
                include "src/main/jastadd/scanner/Preamble.flex",      [-3]
                include "src/main/jastadd/scanner/Macros.flex",        [-2]
                include "src/main/jastadd/scanner/RulesPreamble.flex", [-1]
                include "src/main/jastadd/scanner/Keywords.flex",       [0]
                include "src/main/jastadd/scanner/Symbols.flex",        [1]
                include "src/main/jastadd/scanner/RulesPostamble.flex", [2]
            }

            parser {
                include "src/main/jastadd/parser/Preamble.parser"
                include "src/main/jastadd/parser/RelAst.parser"
            }
        }
    }

    cleanGen.doFirst {
        delete "src/gen"
        delete "src/gen-res"
    }

    preprocessParser.doFirst {

        args += ["--no-beaver-symbol"]

    }

    module = "Preprocessor"

    astPackage = 'org.jastadd.relast.ast'

    parser.name = 'RelAstParser'

    genDir = 'src/gen/java'

    buildInfoDir = 'src/gen-res'

    scanner.genDir = "src/gen/java/org/jastadd/relast/scanner"
    parser.genDir = "src/gen/java/org/jastadd/relast/parser"

    jastaddOptions = ["--lineColumnNumbers", "--List=JastAddList", "--safeLazy", "--visitCheck=true", "--rewrite=cnta", "--cache=all"]
}

generateAst.dependsOn relast

clean.dependsOn(cleanGen)

modelJar.dependsOn(generateAst, modelClasses)
modelClasses.dependsOn(generateAst)
compileJava.dependsOn(modelJar)

jar.dependsOn(modelJar)