Select Git revision
build.gradle.kts

Johannes Mey authored
build.gradle.kts 6.11 KiB
import io.gitlab.arturbosch.detekt.Detekt
import org.jetbrains.changelog.Changelog
import org.jetbrains.changelog.markdownToHTML
import org.jetbrains.grammarkit.tasks.GenerateLexerTask
import org.jetbrains.grammarkit.tasks.GenerateParserTask
import org.jetbrains.kotlin.gradle.tasks.KotlinCompile
fun properties(key: String) = project.findProperty(key).toString()
plugins {
id("idea")
// Java support
id("java")
// Kotlin support
id("org.jetbrains.kotlin.jvm") version "1.8.20"
// gradle-intellij-plugin - read more: https://github.com/JetBrains/gradle-intellij-plugin
id("org.jetbrains.intellij") version "1.13.3"
// gradle-changelog-plugin - read more: https://github.com/JetBrains/gradle-changelog-plugin
id("org.jetbrains.changelog") version "2.0.0"
// detekt linter - read more: https://detekt.github.io/detekt/gradle.html
id("io.gitlab.arturbosch.detekt") version "1.23.0"
// ktlint linter - read more: https://github.com/JLLeitschuh/ktlint-gradle
id("org.jlleitschuh.gradle.ktlint") version "11.3.2"
// grammrkit - read more: https://plugins.gradle.org/plugin/org.jetbrains.grammarkit
id("org.jetbrains.grammarkit") version "2022.3.1"
}
group = properties("pluginGroup")
version = properties("pluginVersion")
// Configure project's dependencies
repositories {
mavenCentral()
}
java {
sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = JavaVersion.VERSION_1_8
}
idea {
module {
generatedSourceDirs.add(file("./src/gen"))
}
}
// Configure gradle-intellij-plugin plugin.
// Read more: https://github.com/JetBrains/gradle-intellij-plugin
intellij {
pluginName.set(properties("pluginName"))
version.set(properties("platformVersion"))
type.set(properties("platformType"))
downloadSources.set(properties("platformDownloadSources").toBoolean())
updateSinceUntilBuild.set(true)
// Plugin Dependencies. Uses `platformPlugins` property from the gradle.properties file.
plugins.set(properties("platformPlugins").split(',').map(String::trim).filter(String::isNotEmpty))
}
sourceSets {
main {
java.srcDir("src/gen/java")
}
}
// Configure gradle-changelog-plugin plugin.
// Read more: https://github.com/JetBrains/gradle-changelog-plugin
changelog {
version.set(properties("pluginVersion"))
groups.set(listOf("Added", "Changed", "Deprecated", "Removed", "Fixed"))
repositoryUrl.set(properties("pluginRepositoryUrl"))
}
// Configure detekt plugin.
// Read more: https://detekt.github.io/detekt/kotlindsl.html
detekt {
source.from(files("build.gradle.kts"))
}
tasks {
val generateGrammarLexer = task<GenerateLexerTask>("generateGrammarLexer") {
sourceFile.set(file("src/main/grammar/Grammar.flex"))
targetDir.set("src/gen/java/org/jastadd/tooling/grammar/lexer/")
targetClass.set("GrammarLexer")
purgeOldFiles.set(true)
}
// not fully working because of https://github.com/JetBrains/gradle-grammar-kit-plugin/issues/3
val generateGrammarParser = task<GenerateParserTask>("generateGrammarParser") {
sourceFile.set(file("src/main/grammar/Grammar.bnf"))
targetRoot.set("src/gen/java")
pathToParser.set("/org/jastadd/tooling/grammar/GrammarParser.java")
pathToPsiRoot.set("/org/jastadd/tooling/grammar/psi")
purgeOldFiles.set(true)
}
val generateAspectLexer = task<GenerateLexerTask>("generateAspectLexer") {
sourceFile.set(file("src/main/grammar/Aspect.flex"))
targetDir.set("src/gen/java/org/jastadd/tooling/aspect/lexer/")
targetClass.set("AspectLexer")
purgeOldFiles.set(true)
}
// not fully working because of https://github.com/JetBrains/gradle-grammar-kit-plugin/issues/3
val generateAspectParser = task<GenerateParserTask>("generateAspectParser") {
sourceFile.set(file("src/main/grammar/Aspect.bnf"))
targetRoot.set("src/gen/java")
pathToParser.set("/org/jastadd/tooling/aspect/AspectParser.java")
pathToPsiRoot.set("/org/jastadd/tooling/aspect/psi")
purgeOldFiles.set(true)
}
compileJava {
dependsOn(generateGrammarLexer)
dependsOn(generateGrammarParser)
dependsOn(generateAspectLexer)
dependsOn(generateAspectParser)
}
// Set the compatibility versions to 1.8
withType<JavaCompile> {
sourceCompatibility = "17"
targetCompatibility = "17"
}
withType<KotlinCompile> {
kotlinOptions.jvmTarget = "17"
}
withType<Detekt> {
jvmTarget = "17"
}
patchPluginXml {
version.set(properties("pluginVersion"))
sinceBuild.set(properties("pluginSinceBuild"))
untilBuild.set(properties("pluginUntilBuild"))
// Extract the <!-- Plugin description --> section from README.md and provide for the plugin's manifest
pluginDescription.set(
File(projectDir, "README.md").readText().lines().run {
val start = "<!-- Plugin description -->"
val end = "<!-- Plugin description end -->"
if (!containsAll(listOf(start, end))) {
throw GradleException("Plugin description section not found in README.md:\n$start ... $end")
}
subList(indexOf(start) + 1, indexOf(end))
}.joinToString("\n").run { markdownToHTML(this) }
)
// Get the latest available change notes from the changelog file
changeNotes.set(provider { changelog.renderItem(changelog.get(properties("pluginVersion")), Changelog.OutputType.HTML) })
}
jar {
dependsOn("patchChangelog")
}
publishPlugin {
dependsOn("patchChangelog")
token.set(System.getenv("PUBLISH_TOKEN"))
// pluginVersion is based on the SemVer (https://semver.org) and supports pre-release labels, like 2.1.7-alpha.3
// Specify pre-release label to publish the plugin in a custom Release Channel automatically. Read more:
// https://plugins.jetbrains.com/docs/intellij/deployment.html#specifying-a-release-channel
channels.set(listOf(properties("pluginVersion").split('-').getOrElse(1) { "default" }.split('.').first()))
}
}