Upgrade Gradle to 6.7.1 and use conventions plugin mechanism.

benchmark/build.gradle

-apply plugin: 'application'
+plugins {
+    id 'eraser.java-application-conventions'
+}
 
 dependencies {
-    compile project(':eraser-base')
-    compile project(':feedbackloop.learner_backup')
-    compile project(':datasets')
+    implementation project(':eraser-base')
+    implementation project(':feedbackloop.learner_backup')
     implementation group: 'com.opencsv', name: 'opencsv', version: '4.1'
-    compile group: 'org.apache.httpcomponents', name: 'httpclient', version: "${apache_httpcomponents_version}"
-    compile group: 'org.apache.httpcomponents', name: 'fluent-hc', version: "${apache_httpcomponents_version}"
-    testCompile group: 'org.apache.logging.log4j', name: 'log4j-slf4j-impl', version: '2.11.2'
-}
-
-run {
-    mainClassName = 'de.tudresden.inf.st.eraser.benchmark.Main'
-    standardInput = System.in
-    if (project.hasProperty("appArgs")) {
-        args Eval.me(appArgs)
-    }
+    implementation group: 'org.apache.httpcomponents', name: 'httpclient', version: "${apache_httpcomponents_version}"
+    implementation group: 'org.apache.httpcomponents', name: 'fluent-hc', version: "${apache_httpcomponents_version}"
+    testImplementation group: 'org.apache.logging.log4j', name: 'log4j-slf4j-impl', version: '2.11.2'
 }
 
-sourceSets {
-    main {
-        java {
-            srcDir 'src/main/java'
-        }
-    }
-}
+application.mainClass = 'de.tudresden.inf.st.eraser.benchmark.Main'

build.gradle

-plugins {
-    id "com.github.ben-manes.versions" version "0.20.0"
-}
-
-allprojects  {
-	group = 'de.tudresden.inf.st'
-	version = '0.1'
-}
-
-subprojects {
-	apply plugin: 'java'
-
-	sourceCompatibility = 1.8
-	targetCompatibility = 1.8
-
-	task packageSources(type: Jar) {
-		classifier = 'sources'
-		from sourceSets.main.allSource
-	}
-
-	artifacts.archives packageSources
-	configurations {
-		testArtifacts.extendsFrom testRuntime
-	}
-
-	task testJar(type: Jar) {
-		classifier "test"
-		from sourceSets.test.output
-	}
-
-	artifacts {
-		testArtifacts testJar
-	}
-
-	repositories {
-		mavenCentral()
-	}
-
-	dependencies {
-		compile group: 'org.apache.logging.log4j', name: 'log4j-api', version: '2.11.2'
-		compile group: 'org.apache.logging.log4j', name: 'log4j-core', version: '2.11.2'
-		testCompile group: 'junit', name: 'junit', version: '4.12'
-		testCompile group: 'org.hamcrest', name: 'hamcrest-junit', version: '2.0.0.0'
-	}
-
-}

buildSrc/build.gradle

+plugins {
+    id 'groovy-gradle-plugin'
+}
+
+repositories {
+    gradlePluginPortal()
+}
+
+dependencies {
+    implementation 'com.github.ben-manes:gradle-versions-plugin:0.36.0'
+}

buildSrc/src/main/groovy/eraser.java-application-conventions.gradle

+plugins {
+  id 'eraser.java-common-conventions'
+  id 'application'
+}

buildSrc/src/main/groovy/eraser.java-common-conventions.gradle

+plugins {
+  id 'java'
+  id 'idea'
+  id 'com.github.ben-manes.versions'
+}
+
+repositories {
+  mavenCentral()
+}
+
+dependencies {
+  implementation group: 'org.apache.logging.log4j', name: 'log4j-api', version: '2.11.2'
+  implementation group: 'org.apache.logging.log4j', name: 'log4j-core', version: '2.11.2'
+  testImplementation group: 'junit', name: 'junit', version: '4.12'
+  testImplementation group: 'org.hamcrest', name: 'hamcrest-junit', version: '2.0.0.0'
+
+  // testImplementation 'org.junit.jupiter:junit-jupiter-api:5.6.2'
+
+  // testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine'
+}
+
+// tasks.named('test') {
+//   useJUnitPlatform()
+// }

buildSrc/src/main/groovy/eraser.java-jastadd-conventions.gradle

+plugins {
+  id 'java'
+  id 'jastadd'
+}
+
+repositories {
+  mavenCentral()
+}
+
+dependencies {
+  implementation group: 'org.jastadd', name: 'jastaddgradle', version: '1.13.2'
+}

commons.color/build.gradle

-dependencies {
-    compile group: 'org.apache.commons', name: 'commons-math3', version: '3.6.1'
+plugins {
+    id 'eraser.java-application-conventions'
+    id 'java-library'
 }
 
-sourceSets {
-    main {
-        java {
-            srcDir 'src/main/java'
-        }
-    }
+dependencies {
+    api group: 'org.apache.commons', name: 'commons-math3', version: '3.6.1'
 }

eraser-base/build.gradle

-apply plugin: 'jastadd'
-apply plugin: 'application'
-apply plugin: 'jacoco'
-apply plugin: 'idea'
-apply plugin: 'distribution'
-
-dependencies {
-    compile group: 'com.fasterxml.jackson.core', name: 'jackson-databind', version: "${jackson_version}"
-    compile group: 'net.sf.beaver', name: 'beaver-rt', version: '0.9.11'
-    compile group: 'org.fusesource.mqtt-client', name: 'mqtt-client', version: '1.15'
-    compile group: 'org.influxdb', name: 'influxdb-java', version: '2.15'
-    testCompile group: 'org.testcontainers', name: 'testcontainers', version: '1.11.2'
-    testCompile group: 'org.testcontainers', name: 'influxdb', version: '1.11.2'
-    testCompile group: 'org.apache.logging.log4j', name: 'log4j-slf4j-impl', version: '2.11.2'
-}
-
 buildscript {
     repositories.mavenLocal()
     repositories.mavenCentral()
@@ -22,14 +6,28 @@ buildscript {
     }
 }
 
-run {
-    mainClassName = 'de.tudresden.inf.st.eraser.Main'
-    standardInput = System.in
-    if (project.hasProperty("appArgs")) {
-        args Eval.me(appArgs)
+plugins {
+    id 'eraser.java-application-conventions'
+    id 'java-library'
+    id 'com.github.ben-manes.versions'
+    id 'jacoco'
+    id 'distribution'
 }
+
+apply plugin: 'jastadd'
+
+dependencies {
+    api group: 'com.fasterxml.jackson.core', name: 'jackson-databind', version: "${jackson_version}"
+    api group: 'net.sf.beaver', name: 'beaver-rt', version: '0.9.11'
+    api group: 'org.fusesource.mqtt-client', name: 'mqtt-client', version: '1.15'
+    implementation group: 'org.influxdb', name: 'influxdb-java', version: '2.15'
+    testImplementation group: 'org.testcontainers', name: 'testcontainers', version: '1.11.2'
+    testImplementation group: 'org.testcontainers', name: 'influxdb', version: '1.11.2'
+    testImplementation group: 'org.apache.logging.log4j', name: 'log4j-slf4j-impl', version: '2.11.2'
 }
 
+application.mainClass = 'de.tudresden.inf.st.eraser.Main'
+
 test {
     testLogging {
         events "passed", "skipped", "failed"
@@ -97,7 +95,7 @@ String[] arguments = ["libs/rd-builder.jar", "-d", "doc/"]
 def allSrcFiles = sourceSets.main.allSource.findAll { it.name.endsWith('java') }.toArray()
 def ragdocViewSrcData = '../ragdoc-view/src/data/'
 
-task ragdoc(type: JavaExec, dependsOn: assemble, overwrite: true) {
+task ragdocFixed(type: JavaExec, dependsOn: assemble) {
     group = 'documentation'
     description = 'Create ragdoc json documentation files'
     main = "-jar"

eraser.spark/build.gradle

 plugins {
-    id 'application'
+    id 'eraser.java-application-conventions'
     id 'io.franzbecker.gradle-lombok' version '3.0.0'
 }
 
 dependencies {
-    compile project(':eraser-base')
-    compile group: 'org.apache.logging.log4j', name: 'log4j-slf4j-impl', version: '2.11.2'
-    compile group: 'com.sparkjava', name: 'spark-core', version: '2.9.0'
+    implementation project(':eraser-base')
+    implementation group: 'org.apache.logging.log4j', name: 'log4j-slf4j-impl', version: '2.11.2'
+    implementation group: 'com.sparkjava', name: 'spark-core', version: '2.9.0'
 }
 
-run {
-    mainClassName = 'de.tudresden.inf.st.eraser.spark.Application'
-    standardInput = System.in
-}
-
-sourceSets {
-    main {
-        java {
-            srcDir 'src/main/java'
-        }
-    }
-}
+application.mainClass = 'de.tudresden.inf.st.eraser.spark.Application'

eraser.starter/build.gradle

 plugins {
-    id 'java'
-    id 'application'
+    id 'eraser.java-application-conventions'
     id 'distribution'
     id 'io.github.http-builder-ng.http-plugin' version '0.1.1'
 }
 
-repositories {
-    mavenCentral()
-}
-
-sourceCompatibility = 1.8
-
 dependencies {
-    compile project(':eraser-base')
-    compile project(':eraser.spark')
-    compile project(':feedbackloop.api')
-    compile project(':feedbackloop.analyze')
-    compile project(':feedbackloop.plan')
-    compile project(':feedbackloop.execute')
-    compile project(':feedbackloop.learner_backup')
-    compile project(':datasets')
-    compile group: 'com.fasterxml.jackson.dataformat', name: 'jackson-dataformat-yaml', version: "${jackson_version}"
-    compile group: 'com.fasterxml.jackson.core', name: 'jackson-databind', version: "${jackson_version}"
-    compile group: 'net.sourceforge.argparse4j', name: 'argparse4j', version: '0.8.1'
-    //    compile project(':feedbackloop.learner')
+    implementation project(':eraser-base')
+    implementation project(':eraser.spark')
+    implementation project(':feedbackloop.api')
+    implementation project(':feedbackloop.analyze')
+    implementation project(':feedbackloop.plan')
+    implementation project(':feedbackloop.execute')
+    implementation project(':feedbackloop.learner_backup')
+    implementation group: 'com.fasterxml.jackson.dataformat', name: 'jackson-dataformat-yaml', version: "${jackson_version}"
+    implementation group: 'com.fasterxml.jackson.core', name: 'jackson-databind', version: "${jackson_version}"
+    implementation group: 'net.sourceforge.argparse4j', name: 'argparse4j', version: '0.8.1'
+    //    implementation project(':feedbackloop.learner')
 
 }
 
-run {
-    mainClassName = 'de.tudresden.inf.st.eraser.starter.EraserStarter'
-    standardInput = System.in
-}
+application.mainClass = 'de.tudresden.inf.st.eraser.starter.EraserStarter'
 
 import io.github.httpbuilderng.http.HttpTask
 
@@ -46,23 +35,6 @@ task shutdown (type: HttpTask) {
     }
 }
 
-sourceSets {
-    main {
-        java {
-            srcDir 'src/main/java'
-        }
-    }
-}
-
-//distributions {
-//    main {
-//        contents {
-//            from {
-//                'src/main/resources/starter.eraser'
-//            }
-//        }
-//    }
-//}
 applicationDistribution.from("src/main/resources") {
     include "starter.eraser"
 }

feedbackloop.analyze/build.gradle

-dependencies {
-    compile project(':eraser-base')
-    compile project(':feedbackloop.api')
+plugins {
+    id 'eraser.java-common-conventions'
 }
 
-sourceSets {
-    main {
-        java {
-            srcDir 'src/main/java'
-        }
-    }
+dependencies {
+    implementation project(':eraser-base')
+    implementation project(':feedbackloop.api')
 }

feedbackloop.api/build.gradle

 plugins {
+    id 'eraser.java-common-conventions'
     id 'io.franzbecker.gradle-lombok' version '3.0.0'
 }
 
 dependencies {
-    compile project(':eraser-base')
+    implementation project(':eraser-base')
     compile project(':commons.color')
     compile group: 'org.encog', name: 'encog-core', version: '3.4'
 }
-
-sourceSets {
-    main {
-        java {
-            srcDir 'src/main/java'
-        }
-    }
-}

feedbackloop.execute/build.gradle

-dependencies {
-    compile project(':eraser-base')
-    compile project(':feedbackloop.api')
+plugins {
+    id 'eraser.java-common-conventions'
 }
 
-sourceSets {
-    main {
-        java {
-            srcDir 'src/main/java'
-        }
-    }
+dependencies {
+    implementation project(':eraser-base')
+    implementation project(':feedbackloop.api')
 }

feedbackloop.learner/build.gradle

-apply plugin: 'application'
-
-dependencies {
-    compile project(':eraser-base')
-    compile project(':feedbackloop.api')
-    compile group: 'org.encog', name: 'encog-core', version: '3.4'
+plugins {
+    id 'eraser.java-application-conventions'
 }
 
-run {
-    mainClassName = 'de.tudresden.inf.st.eraser.feedbackloop.learner.Main'
-    standardInput = System.in
-    if (project.hasProperty("appArgs")) {
-        args Eval.me(appArgs)
-    }
+dependencies {
+    implementation project(':eraser-base')
+    implementation project(':feedbackloop.api')
+    implementation group: 'org.encog', name: 'encog-core', version: '3.4'
 }
 
-sourceSets {
-    main {
-        java {
-            srcDir 'src/main/java'
-        }
-    }
-}
+application.mainClass = 'de.tudresden.inf.st.eraser.feedbackloop.learner.Main'

feedbackloop.learner_backup/build.gradle

 plugins {
-    id 'application'
+    id 'eraser.java-application-conventions'
     id 'io.franzbecker.gradle-lombok' version '3.0.0'
 }
 
 dependencies {
-    compile project(':eraser-base')
-    compile group: 'com.fasterxml.jackson.core', name: 'jackson-databind', version: "${jackson_version}"
-    compile group: 'org.encog', name: 'encog-core', version: '3.4'
+    implementation project(':eraser-base')
+    implementation group: 'com.fasterxml.jackson.core', name: 'jackson-databind', version: "${jackson_version}"
+    implementation group: 'org.encog', name: 'encog-core', version: '3.4'
     implementation group: 'com.opencsv', name: 'opencsv', version: '4.1'
     implementation group: 'commons-io', name: 'commons-io', version: '2.5'
     implementation group: 'org.apache.httpcomponents', name: 'httpclient', version: "${apache_httpcomponents_version}"
@@ -16,16 +16,4 @@ dependencies {
 //    compile group: 'com.sparkjava', name: 'spark-core', version: '2.9.0'
 }
 
-run {
-    mainClassName = 'de.tudresden.inf.st.eraser.feedbackloop.learner_backup.Main'
-    standardInput = System.in
-    if (project.hasProperty("appArgs")) {
-        args Eval.me(appArgs)
-    }
-}
-
-sourceSets.main {
-    java {
-        srcDir 'src/main/java'
-    }
-}
+application.mainClass = 'de.tudresden.inf.st.eraser.feedbackloop.learner_backup.Main'

feedbackloop.main/build.gradle

-apply plugin: 'application'
-
-dependencies {
-    compile project(':eraser-base')
-    compile project(':feedbackloop.api')
-    compile project(':feedbackloop.monitor')
-    compile project(':feedbackloop.analyze')
-    compile project(':feedbackloop.plan')
-    compile project(':feedbackloop.execute')
+plugins {
+    id 'eraser.java-application-conventions'
 }
 
-run {
-    mainClassName = 'de.tudresden.inf.st.eraser.feedbackloop.main.Main'
-    standardInput = System.in
-    if (project.hasProperty("appArgs")) {
-        args Eval.me(appArgs)
-    }
+dependencies {
+    implementation project(':eraser-base')
+    implementation project(':feedbackloop.api')
+    implementation project(':feedbackloop.monitor')
+    implementation project(':feedbackloop.analyze')
+    implementation project(':feedbackloop.plan')
+    implementation project(':feedbackloop.execute')
 }
 
-sourceSets {
-    main {
-        java {
-            srcDir 'src/main/java'
-        }
-    }
-}
+application.mainClass = 'de.tudresden.inf.st.eraser.feedbackloop.main.Main'

feedbackloop.monitor/build.gradle

-apply plugin: 'application'
-
-dependencies {
-    compile project(':eraser-base')
-    compile project(':feedbackloop.api')
+plugins {
+    id 'eraser.java-application-conventions'
 }
 
-run {
-    mainClassName = 'de.tudresden.inf.st.eraser.feedbackloop.monitor.Main'
-    standardInput = System.in
-    if (project.hasProperty("appArgs")) {
-        args Eval.me(appArgs)
-    }
+dependencies {
+    implementation project(':eraser-base')
+    implementation project(':feedbackloop.api')
 }
 
-sourceSets {
-    main {
-        java {
-            srcDir 'src/main/java'
-        }
-    }
-}
+application.mainClass = 'de.tudresden.inf.st.eraser.feedbackloop.monitor.Main'

feedbackloop.plan/build.gradle

-apply plugin: 'application'
+plugins {
+    id 'eraser.java-application-conventions'
+}
 
 dependencies {
-    compile project(':eraser-base')
+    implementation project(':eraser-base')
     compile project(':feedbackloop.api')
 }
 
-run {
-    mainClassName = 'de.tudresden.inf.st.eraser.feedbackloop.plan.Main'
-    standardInput = System.in
-    if (project.hasProperty("appArgs")) {
-        args Eval.me(appArgs)
-    }
-}
-
-sourceSets {
-    main {
-        java {
-            srcDir 'src/main/java'
-        }
-    }
-}
+application.mainClass = 'de.tudresden.inf.st.eraser.feedbackloop.plan.Main'

gradle/wrapper/gradle-wrapper.properties

-#Tue May 07 14:40:56 CEST 2019
 distributionBase=GRADLE_USER_HOME
 distributionPath=wrapper/dists
+distributionUrl=https\://services.gradle.org/distributions/gradle-6.7.1-bin.zip
 zipStoreBase=GRADLE_USER_HOME
 zipStorePath=wrapper/dists
-distributionUrl=https\://services.gradle.org/distributions/gradle-4.10.2-all.zip