aspect GenerationUtils {
  public static final String ASTNode.aspectIndent = "  ";

  public String ASTNode.ind(int n) {
    StringBuilder s = new StringBuilder();
    for (int i = 0; i < n; i++) {
      s.append(aspectIndent);
    }
    return s.toString();
  }

  // --- prettyPrint ---
  syn String MappingDefinitionType.prettyPrint();
  eq JavaMappingDefinitionType.prettyPrint() = getType().getName();
  eq JavaArrayMappingDefinitionType.prettyPrint() = getType().getName() + "[]";

  syn String JavaTypeUse.prettyPrint() {
    StringBuilder sb = new StringBuilder();
    generateAbstractGrammar(sb);
    return sb.toString();
  }
}

/* Open questions
- Should all string constants be defined on the normal AST, or on the special mustache AST?
*/

aspect AttributesForMustache {
  // --- MRos2Rag ---
  eq MRos2Rag.getChild().mqttUpdaterAttribute() = mqttUpdaterAttribute();
  eq MRos2Rag.getChild().mqttUpdaterField() = mqttUpdaterField();

  syn String MRos2Rag.mqttUpdaterAttribute() = getRos2Rag().mqttUpdaterAttribute();
  syn String MRos2Rag.mqttUpdaterField() = getRos2Rag().mqttUpdaterField();
  syn String MRos2Rag.mqttSetHostMethod() = getRos2Rag().mqttSetHostMethod();
  syn String MRos2Rag.mqttWaitUntilReadyMethod() = getRos2Rag().mqttWaitUntilReadyMethod();
  syn String MRos2Rag.mqttCloseMethod() = getRos2Rag().mqttCloseMethod();

  // --- MUpdateDefinition ---
  syn String MUpdateDefinition.preemptiveExpectedValue();
  syn String MUpdateDefinition.preemptiveReturn();
  syn TokenUpdateDefinition MUpdateDefinition.updateDef();
  syn String MUpdateDefinition.firstInputVarName();

  eq MUpdateDefinition.getInnerMappingDefinition(int i).isLast() = i == getNumInnerMappingDefinition() - 1;
  eq MUpdateDefinition.getInnerMappingDefinition().resultVarPrefix() = resultVarPrefix();
  eq MUpdateDefinition.getInnerMappingDefinition(int i).inputVarName() = i == 0 ? firstInputVarName() : resultVarPrefix() + getInnerMappingDefinition(i - 1).getMappingDefinition().methodName();

  inh String MUpdateDefinition.mqttUpdaterAttribute();

  syn String MUpdateDefinition.connectMethod() = updateDef().connectMethod();
  syn TokenComponent MUpdateDefinition.token() = updateDef().getToken();
  syn boolean MUpdateDefinition.alwaysApply() = updateDef().getAlwaysApply();
  syn String MUpdateDefinition.resultVarPrefix() = "result";  // we do not need "_" here, because methodName begins with one
  syn String MUpdateDefinition.parentTypeName() = token().containingTypeDecl().getName();
  syn String MUpdateDefinition.tokenName() = token().getName();
  syn MInnerMappingDefinition MUpdateDefinition.lastDefinition() = getInnerMappingDefinition(getNumInnerMappingDefinition() - 1);
  syn String MUpdateDefinition.lastDefinitionToType() = lastDefinition().ToType();
  syn String MUpdateDefinition.lastDefinitionName() = lastDefinition().methodName();
  syn String MUpdateDefinition.lastResult() = resultVarPrefix() + lastDefinitionName();
  syn String MUpdateDefinition.condition() {
    if (lastDefinition().getMappingDefinition().getToType().isArray()) {
      return "java.util.Arrays.equals(" + preemptiveExpectedValue() + ", " + lastResult() + ")";
    }
    if (token().isPrimitiveType() && lastDefinition().getMappingDefinition().getToType().isPrimitiveType()) {
      return preemptiveExpectedValue() + " == " + lastResult();
    }
    if (lastDefinition().getMappingDefinition().isDefaultMappingDefinition()) {
      return preemptiveExpectedValue() + " != null && " + preemptiveExpectedValue() + ".equals(" + lastResult() + ")";
    }
    return preemptiveExpectedValue() + " != null ? " + preemptiveExpectedValue() + ".equals(" + lastResult() + ") : " + lastResult() + " == null";
  }

  // --- MInnerMappingDefinition ---
  inh boolean MInnerMappingDefinition.isLast();
  inh String MInnerMappingDefinition.resultVarPrefix();
  syn String MInnerMappingDefinition.ToType() = getMappingDefinition().getToType().prettyPrint();
  syn String MInnerMappingDefinition.methodName() = getMappingDefinition().methodName();
  inh String MInnerMappingDefinition.inputVarName();

  // --- MReadDefinition ---
  eq MReadDefinition.preemptiveExpectedValue() = "get" + tokenName() + "()";
  eq MReadDefinition.preemptiveReturn() = "return;";
  eq MReadDefinition.updateDef() = getReadFromMqttDefinition();
  eq MReadDefinition.firstInputVarName() = "message";

  // --- MWriteDefinition ---
  eq MWriteDefinition.preemptiveExpectedValue() = lastValue();
  eq MWriteDefinition.preemptiveReturn() = "return false;";
  eq MWriteDefinition.updateDef() = getWriteToMqttDefinition();
  eq MWriteDefinition.firstInputVarName() = "get" + tokenName() + "()";

  syn String MWriteDefinition.writeTopic() = getWriteToMqttDefinition().writeTopic();
  syn String MWriteDefinition.lastValue() = getWriteToMqttDefinition().lastValue();
  syn String MWriteDefinition.updateMethod() = getWriteToMqttDefinition().updateMethod();
  syn String MWriteDefinition.writeMethod() = getWriteToMqttDefinition().writeMethod();
  syn String MWriteDefinition.tokenResetMethod() = getWriteToMqttDefinition().tokenResetMethod();

  // --- MMappingDefinition ---
  syn String MMappingDefinition.toType() = getMappingDefinition().getToType().prettyPrint();
  syn String MMappingDefinition.methodName() = getMappingDefinition().methodName();
  syn String MMappingDefinition.fromType() = getMappingDefinition().getFromType().prettyPrint();
  syn String MMappingDefinition.fromVariableName() = getMappingDefinition().getFromVariableName();
  syn String MMappingDefinition.content() = getMappingDefinition().getContent();

  // --- MDependencyDefinition ---
  syn String MDependencyDefinition.targetParentTypeName() = getDependencyDefinition().getTarget().containingTypeDecl().getName();
  syn String MDependencyDefinition.dependencyMethod() = getDependencyDefinition().dependencyMethod();
  syn String MDependencyDefinition.sourceParentTypeName() = getDependencyDefinition().getSource().containingTypeDecl().getName();
  syn String MDependencyDefinition.internalRelationPrefix() = getDependencyDefinition().internalRelationPrefix();
  syn nta MUpdateDefinition MDependencyDefinition.targetUpdateDefinition() {
    return getDependencyDefinition().targetUpdateDefinition().toMustache();
  }

  // --- MTypeComponent ---
  syn String MTypeComponent.name() = getTypeComponent().getName();
  inh String MTypeComponent.mqttUpdaterAttribute();
  inh String MTypeComponent.mqttUpdaterField();

  // --- MTokenComponent ---
  syn String MTokenComponent.parentTypeName() = getTokenComponent().containingTypeDecl().getName();
  syn String MTokenComponent.name() = getTokenComponent().getName();
  syn String MTokenComponent.javaType() = getTokenComponent().getJavaTypeUse().prettyPrint();
  syn String MTokenComponent.internalName() = getTokenComponent().internalName();

  // --- toMustache ---
  syn lazy MRos2Rag Ros2Rag.toMustache() {
    MRos2Rag result = new MRos2Rag();
    result.setRos2Rag(this);
    for (UpdateDefinition def : getUpdateDefinitionList()) {
      if (def.isWriteToMqttDefinition()) {
        result.addWriteDefinition(def.asWriteToMqttDefinition().toMustache());
      } else {
        result.addReadDefinition(def.asReadFromMqttDefinition().toMustache());
      }
    }
    for (MappingDefinition def : allMappingDefinitions()) {
      result.addMappingDefinition(def.toMustache());
    }
    for (DependencyDefinition def : getDependencyDefinitionList()) {
      result.addDependencyDefinition(def.toMustache());
    }
    for (TokenComponent token : getProgram().allTokenComponents()) {
      if (!token.getDependencySourceDefinitionList().isEmpty()) {
        result.addTokenComponent(token.toMustache());
      }
    }
    for (Component child : rootNode.getComponentList()) {
      if (child.isTypeComponent()) {
        result.addRootTypeComponent(child.asTypeComponent().toMustache());
      }
    }
    return result;
  }

//MInnerMappingDefinition.MappingDefinition -> MappingDefinition;
  protected void MUpdateDefinition.addInnerMappings() {
    for (MappingDefinition def : updateDef().effectiveMappings()) {
      MInnerMappingDefinition inner = new MInnerMappingDefinition();
      inner.setMappingDefinition(def);
      addInnerMappingDefinition(inner);
    }
  }
  syn lazy MReadDefinition ReadFromMqttDefinition.toMustache() {
    MReadDefinition result = new MReadDefinition();
    result.setReadFromMqttDefinition(this);
    result.addInnerMappings();
    return result;
  }
  syn lazy MWriteDefinition WriteToMqttDefinition.toMustache() {
    MWriteDefinition result = new MWriteDefinition();
    result.setWriteToMqttDefinition(this);
    result.addInnerMappings();
    return result;
  }
  syn lazy MMappingDefinition MappingDefinition.toMustache() {
    MMappingDefinition result = new MMappingDefinition();
    result.setMappingDefinition(this);
    return result;
  }
  syn lazy MDependencyDefinition DependencyDefinition.toMustache() {
    MDependencyDefinition result = new MDependencyDefinition();
    result.setDependencyDefinition(this);
    return result;
  }
  syn lazy MTypeComponent TypeComponent.toMustache() {
    MTypeComponent result = new MTypeComponent();
    result.setTypeComponent(this);
    return result;
  }
  syn lazy MTokenComponent TokenComponent.toMustache() {
    MTokenComponent result = new MTokenComponent();
    result.setTokenComponent(this);
    for (DependencyDefinition def : getDependencySourceDefinitionList()) {
      result.addDependencyDefinition(def.toMustache());
    }
    return result;
  }
}

aspect AspectGeneration {
  // naming convention attributes
  syn String TokenComponent.internalName() = getDependencySourceDefinitionList().isEmpty() ? externalName() : "_internal_" + getName();
  syn String TokenComponent.externalName() = getName();

  syn String TokenUpdateDefinition.connectMethod() = "connect" + getToken().getName();
  syn String WriteToMqttDefinition.writeTopic() = "_topic_" + getToken().getName();
  syn String WriteToMqttDefinition.lastValue() = "_lastValue" + getToken().getName();
  syn String WriteToMqttDefinition.updateMethod() = "_update_" + getToken().getName();
  syn String WriteToMqttDefinition.writeMethod() = "_writeLastValue_" + getToken().getName();
  syn String WriteToMqttDefinition.tokenResetMethod() = "get" + getToken().getName() + "_reset";
  syn String MappingDefinition.methodName() = "_apply_" + getID();
  syn String DependencyDefinition.dependencyMethod() = "add" +
    Character.toUpperCase(getID().charAt(0)) +
    getID().substring(1);
  syn String DependencyDefinition.internalRelationPrefix() = "_internal_" + getID();
  syn String DependencyDefinition.internalTokenName() = getSource().internalName();

  syn String Ros2Rag.mqttUpdaterAttribute() = "_mqttUpdater";
  syn String Ros2Rag.mqttUpdaterField() = "_mqttUpdater";

  syn String Ros2Rag.mqttSetHostMethod() = "MqttSetHost";
  syn String Ros2Rag.mqttWaitUntilReadyMethod() = "MqttWaitUntilReady";
  syn String Ros2Rag.mqttCloseMethod() = "MqttCloseConnections";

  // naming copy attributes
  // --- mqttUpdaterAttribute ---
  inh String UpdateDefinition.mqttUpdaterAttribute();
  inh String MappingDefinition.mqttUpdaterAttribute();
  inh String DependencyDefinition.mqttUpdaterAttribute();
  eq Ros2Rag.getChild().mqttUpdaterAttribute() = mqttUpdaterAttribute();

  // --- rootNodeName ---
  syn String ASTNode.rootNodeName() = rootNode.getName();

  public String Ros2Rag.generateAspect(String rootNodeName) {
    rootNode = getProgram().resolveTypeDecl(rootNodeName);
    return toMustache().generateAspect();
  }

  public String MRos2Rag.generateAspect() {
    StringBuilder sb = new StringBuilder();
    com.github.mustachejava.reflect.ReflectionObjectHandler roh = new com.github.mustachejava.reflect.ReflectionObjectHandler() {
      @Override
      public com.github.mustachejava.Binding createBinding(String name, final com.github.mustachejava.TemplateContext tc, com.github.mustachejava.Code code) {
        return new com.github.mustachejava.reflect.GuardedBinding(this, name, tc, code) {
          @Override
          protected synchronized com.github.mustachejava.util.Wrapper getWrapper(String name, java.util.List<Object> scopes) {
            com.github.mustachejava.util.Wrapper wrapper = super.getWrapper(name, scopes);
            if (wrapper instanceof com.github.mustachejava.reflect.MissingWrapper) {
              throw new com.github.mustachejava.MustacheException(name + " not found in " + tc);
            }
            return wrapper;
          }
        };
      }
    };
    com.github.mustachejava.DefaultMustacheFactory mf = new com.github.mustachejava.DefaultMustacheFactory();
    mf.setObjectHandler(roh);
    com.github.mustachejava.Mustache m = mf.compile("ros2rag.mustache");
    m.execute(new java.io.PrintWriter(new org.jastadd.ros2rag.compiler.AppendableWriter(sb)), this);
    return sb.toString();
  }
}

aspect RelationGeneration {
  syn java.util.List<Relation> Ros2Rag.additionalRelations() {
    java.util.List<Relation> result = new java.util.ArrayList<>();
    for (DependencyDefinition dd : getDependencyDefinitionList()) {
      result.add(dd.getRelationToCreate());
    }
    return result;
  }

  syn nta Relation DependencyDefinition.getRelationToCreate() {
    BidirectionalRelation result = new BidirectionalRelation();
    NavigableRole left = new ListRole(internalRelationPrefix() + "Source");
    left.setType(getTarget().containingTypeDecl());
    NavigableRole right = new ListRole(internalRelationPrefix() + "Target");
    right.setType(getSource().containingTypeDecl());
    result.setLeft(left);
    result.setRight(right);
    return result;
  }
}

aspect GrammarExtension {
  refine BackendAbstractGrammar public void TokenComponent.generateAbstractGrammar(StringBuilder b) {
    if (getNTA()) {
      b.append("/");
    }
    b.append("<");
    if (!getName().equals("")) {
      b.append(internalName()).append(":");
    }
    getJavaTypeUse().generateAbstractGrammar(b);
    b.append(">");
    if (getNTA()) {
      b.append("/");
    }
  }
}