RagConnect.parser

RagConnect ragconnect
  = endpoint_definition.d ragconnect.r       {: r.getEndpointDefinitionList().insertChild(d, 0); return r; :}
  | dependency_definition.d ragconnect.r   {: r.getDependencyDefinitionList().insertChild(d, 0); return r; :}
  | mapping_definition.d ragconnect.r      {: r.getMappingDefinitionList().insertChild(d, 0); return r; :}
  | comment ragconnect.r                   {: return r; :}
  |                                     {: return new RagConnect(); :}
;

%embed {:
  private Iterable<String> makeMappingDefs(ArrayList<?> raw_mapping_defs) {
    return () -> raw_mapping_defs.stream().map(raw -> ((Symbol) raw).value.toString()).iterator();
  }
:} ;

EndpointDefinition endpoint_definition
  = RECEIVE ID.type_name DOT ID.token_name SCOL
    {:
      ReceiveFromMqttDefinition result = new ReceiveFromMqttDefinition();
      result.setToken(TokenComponent.createRef(type_name + "." + token_name));
      return result;
    :}
  | RECEIVE ID.type_name DOT ID.token_name USING string_list.mapping_defs SCOL
    {:
      ReceiveFromMqttDefinition result = new ReceiveFromMqttDefinition();
      result.setToken(TokenComponent.createRef(type_name + "." + token_name));
      for (String mapping_def : makeMappingDefs(mapping_defs)) {
        result.addMapping(MappingDefinition.createRef(mapping_def));
      }
      return result;
    :}
  | SEND ID.type_name DOT ID.token_name SCOL
    {:
      SendToMqttDefinition result = new SendToMqttDefinition();
      result.setToken(TokenComponent.createRef(type_name + "." + token_name));
      return result;
    :}
  | SEND ID.type_name DOT ID.token_name USING string_list.mapping_defs SCOL
    {:
      SendToMqttDefinition result = new SendToMqttDefinition();
      result.setToken(TokenComponent.createRef(type_name + "." + token_name));
      for (String mapping_def : makeMappingDefs(mapping_defs)) {
        result.addMapping(MappingDefinition.createRef(mapping_def));
      }
      return result;
    :}
;

ArrayList string_list
  = ID
  | string_list COMMA ID
;

DependencyDefinition dependency_definition
  = ID.target_type DOT ID.target_token CAN_DEPEND_ON ID.source_type DOT ID.source_token AS ID.id SCOL
    {:
      DependencyDefinition result = new DependencyDefinition();
      result.setSource(TokenComponent.createRef(source_type + "." + source_token));
      result.setTarget(TokenComponent.createRef(target_type + "." + target_token));
      result.setID(id);
      return result;
    :}
;

MappingDefinition mapping_definition
  = ID.id MAPS mapping_type.from_type ID.from_name TO mapping_type.to_type MAPPING_CONTENT.content
    {:
      MappingDefinition result = new MappingDefinition();
      result.setID(id);
      result.setFromType(from_type);
      result.setFromVariableName(from_name);
      result.setToType(to_type);
      result.setContent(content.substring(2, content.length() - 2));
      return result;
    :}
;

MappingDefinitionType mapping_type
  = java_type_use.type
    {:
      JavaMappingDefinitionType result = new JavaMappingDefinitionType();
      result.setType(type);
      return result;
    :}
  | java_type_use.type LBRACKET RBRACKET
    {:
      JavaArrayMappingDefinitionType result = new JavaArrayMappingDefinitionType();
      result.setType(type);
      return result;
    :}
;