apply plugin: 'jastadd'
apply plugin: 'application'

sourceCompatibility = 1.8

mainClassName = 'org.jastadd.ragconnect.compiler.Compiler'

repositories {
    jcenter()
}

buildscript {
    repositories.jcenter()
    dependencies {
        classpath 'org.jastadd:jastaddgradle:1.13.3'
    }
}

dependencies {
    implementation project(':relast.preprocessor')
    implementation group: 'com.github.spullara.mustache.java', name: 'compiler', version: '0.9.6'
    implementation group: 'org.apache.logging.log4j', name: 'log4j-jul', version: '2.11.2'
    runtime group: 'org.jastadd', name: 'jastadd', version: '2.3.4'
    api group: 'net.sf.beaver', name: 'beaver-rt', version: '0.9.11'
}

def versionFile = 'src/main/resources/ragConnectVersion.properties'
def oldProps = new Properties()

try {
    file(versionFile).withInputStream { stream -> oldProps.load(stream) }
    version = oldProps['version']
} catch (e) {
    // this happens, if either the properties file is not present, or cannot be read from
    throw new GradleException("File ${versionFile} not found or unreadable. Aborting.", e)
}

task newVersion() {
    doFirst {
        def props = new Properties()
        props['version'] = value
        props.store(file(versionFile).newWriter(), null)
    }
}

sourceSets {
    main {
        java.srcDir "src/gen/java"
    }
}

test {
    useJUnitPlatform()

    maxHeapSize = '1G'
}

jar {
    manifest {
        attributes "Main-Class": 'org.jastadd.ragconnect.compiler.Compiler'
    }

    from {
        configurations.compile.collect { it.isDirectory() ? it : zipTree(it) }
    }
}

task relast(type: JavaExec) {
    group = 'Build'
    main = "-jar"

    doFirst {
        delete "src/gen/jastadd/*.ast"
        delete "src/gen/jastadd/RagConnect.jadd"
        delete "src/gen/jastadd/RagConnectRefResolver.jadd"
        delete "src/gen/jastadd/RagConnectResolverStubs.jrag"
        mkdir  "src/gen/jastadd/"
    }

    args = [
            "../libs/relast.jar",
            "../relast.preprocessor/src/main/jastadd/RelAst.relast",
            "./src/main/jastadd/RagConnect.relast",
            "./src/main/jastadd/MustacheNodes.relast",
            "--listClass=java.util.ArrayList",
            "--jastAddList=JastAddList",
            "--useJastAddNames",
            "--file",
            "--resolverHelper",
            "--grammarName=./src/gen/jastadd/RagConnect"
    ]

    inputs.files file("../libs/relast.jar"),
            file("../relast.preprocessor/src/main/jastadd/RelAST.relast"),
            file("./src/main/jastadd/RagConnect.relast")
            file("./src/main/jastadd/MustacheNodes.relast")
    outputs.files file("./src/gen/jastadd/RagConnect.ast"),
            file("./src/gen/jastadd/RagConnect.jadd"),
            file("./src/gen/jastadd/RagConnectRefResolver.jadd"),
            file('./src/gen/jastadd/RagConnectResolverStubs.jrag')
}

jastadd {
    configureModuleBuild()
    modules {
        //noinspection GroovyAssignabilityCheck
        module("RagConnect") {

            java {
                basedir ".."
                include "relast.preprocessor/main/**/*.java"
                include "relast.preprocessor/gen/**/*.java"
                include "ragconnect.base/src/main/**/*.java"
                include "ragconnect.base/src/gen/**/*.java"
            }

            jastadd {
                basedir ".."
                include "relast.preprocessor/src/main/jastadd/**/*.ast"
                include "relast.preprocessor/src/main/jastadd/**/*.jadd"
                include "relast.preprocessor/src/main/jastadd/**/*.jrag"
                include "ragconnect.base/src/main/jastadd/**/*.ast"
                include "ragconnect.base/src/main/jastadd/**/*.jadd"
                include "ragconnect.base/src/main/jastadd/**/*.jrag"
                include "ragconnect.base/src/gen/jastadd/**/*.ast"
                include "ragconnect.base/src/gen/jastadd/**/*.jadd"
                include "ragconnect.base/src/gen/jastadd/**/*.jrag"
            }

            scanner {
                basedir ".."
                include "ragconnect.base/src/main/jastadd/scanner/Header.flex",               [-5]
                include "relast.preprocessor/src/main/jastadd/scanner/Preamble.flex",      [-4]
                include "relast.preprocessor/src/main/jastadd/scanner/Macros.flex",        [-3]
                include "ragconnect.base/src/main/jastadd/scanner/Macros.flex",               [-3]
                include "relast.preprocessor/src/main/jastadd/scanner/RulesPreamble.flex", [-2]
                include "ragconnect.base/src/main/jastadd/scanner/MappingContent.flex",       [-1]
                include "ragconnect.base/src/main/jastadd/scanner/Keywords.flex"
                include "relast.preprocessor/src/main/jastadd/scanner/Keywords.flex"
                include "relast.preprocessor/src/main/jastadd/scanner/Symbols.flex",        [1]
                include "relast.preprocessor/src/main/jastadd/scanner/RulesPostamble.flex", [2]
            }

            parser {
                basedir ".."
                include "ragconnect.base/src/main/jastadd/parser/Preamble.parser"
                include "ragconnect.base/src/main/jastadd/parser/RagConnect.parser"
                include "relast.preprocessor/src/main/jastadd/parser/RelAst.parser"
            }
        }
    }

    cleanGen.doFirst {
        delete "src/gen/java/org"
        delete "src/gen-res/BuildInfo.properties"
    }

    preprocessParser.doFirst {

        args += ["--no-beaver-symbol"]

    }

    module = "RagConnect"

    astPackage = 'org.jastadd.ragconnect.ast'

    parser.name = 'RagConnectParser'

    genDir = 'src/gen/java'

    buildInfoDir = 'src/gen-res'

    scanner.genDir = "src/gen/java/org/jastadd/ragconnect/scanner"
    parser.genDir = "src/gen/java/org/jastadd/ragconnect/parser"

    jastaddOptions = ["--lineColumnNumbers", "--List=JastAddList", "--safeLazy", "--visitCheck=true", "--rewrite=cnta", "--cache=all"]
}

generateAst.dependsOn relast