Mappings.jrag

aspect DefaultMappings {

  private String RagConnect.baseDefaultMappingTypeNamePart(String typeName) {
    return capitalize(typeName).replace("[]", "s");
  }

  private MappingDefinitionType RagConnect.baseDefaultMappingTypeFromName(String typeName) {
    return typeName.endsWith("[]") ?
        new JavaArrayMappingDefinitionType(new SimpleJavaTypeUse(typeName.replace("[]", ""))) :
        new JavaMappingDefinitionType(new SimpleJavaTypeUse(typeName));
  }

  private DefaultMappingDefinition RagConnect.baseDefaultMappingDefinition(String fromTypeName, String toTypeName, String content) {
    DefaultMappingDefinition result = new DefaultMappingDefinition();
    result.setID("_Default" + baseDefaultMappingTypeNamePart(fromTypeName) + "To" + baseDefaultMappingTypeNamePart(toTypeName) + "Mapping");
    result.setFromType(baseDefaultMappingTypeFromName(fromTypeName));
    result.setFromVariableName("input");
    result.setToType(baseDefaultMappingTypeFromName(toTypeName));
    result.setContent(content);
    return result;
  }

  syn nta DefaultMappingDefinition RagConnect.defaultBytesToIntMapping() = baseDefaultMappingDefinition(
      "byte[]", "int", "return java.nio.ByteBuffer.wrap(input).getInt();");
  syn nta DefaultMappingDefinition RagConnect.defaultBytesToShortMapping() = baseDefaultMappingDefinition(
      "byte[]", "short", "return java.nio.ByteBuffer.wrap(input).getShort();");
  syn nta DefaultMappingDefinition RagConnect.defaultBytesToLongMapping() = baseDefaultMappingDefinition(
      "byte[]", "long", "return java.nio.ByteBuffer.wrap(input).getLong();");
  syn nta DefaultMappingDefinition RagConnect.defaultBytesToFloatMapping() = baseDefaultMappingDefinition(
      "byte[]", "float", "return java.nio.ByteBuffer.wrap(input).getFloat();");
  syn nta DefaultMappingDefinition RagConnect.defaultBytesToDoubleMapping() = baseDefaultMappingDefinition(
      "byte[]", "double", "return java.nio.ByteBuffer.wrap(input).getDouble();");
  syn nta DefaultMappingDefinition RagConnect.defaultBytesToCharMapping() = baseDefaultMappingDefinition(
      "byte[]", "char", "return java.nio.ByteBuffer.wrap(input).getChar();");
  syn nta DefaultMappingDefinition RagConnect.defaultBytesToStringMapping() = baseDefaultMappingDefinition(
      "byte[]", "String", "return new String(input);");

  syn nta DefaultMappingDefinition RagConnect.defaultIntToBytesMapping() = baseDefaultMappingDefinition(
      "int", "byte[]", "return java.nio.ByteBuffer.allocate(Integer.BYTES).putInt(input).array();");
  syn nta DefaultMappingDefinition RagConnect.defaultShortToBytesMapping() = baseDefaultMappingDefinition(
      "short", "byte[]", "return java.nio.ByteBuffer.allocate(Short.BYTES).putShort(input).array();");
  syn nta DefaultMappingDefinition RagConnect.defaultLongToBytesMapping() = baseDefaultMappingDefinition(
      "long", "byte[]", "return java.nio.ByteBuffer.allocate(Long.BYTES).putLong(input).array();");
  syn nta DefaultMappingDefinition RagConnect.defaultFloatToBytesMapping() = baseDefaultMappingDefinition(
      "float", "byte[]", "return java.nio.ByteBuffer.allocate(Float.BYTES).putFloat(input).array();");
  syn nta DefaultMappingDefinition RagConnect.defaultDoubleToBytesMapping() = baseDefaultMappingDefinition(
      "double", "byte[]", "return java.nio.ByteBuffer.allocate(Double.BYTES).putDouble(input).array();");
  syn nta DefaultMappingDefinition RagConnect.defaultCharToBytesMapping() = baseDefaultMappingDefinition(
      "char", "byte[]", "return java.nio.ByteBuffer.allocate(Character.BYTES).putChar(input).array();");
  syn nta DefaultMappingDefinition RagConnect.defaultStringToBytesMapping() = baseDefaultMappingDefinition(
      "String", "byte[]", "return input.getBytes();");

  syn nta DefaultMappingDefinition RagConnect.defaultStringToIntMapping() = baseDefaultMappingDefinition(
      "String", "int", "return Integer.parseInt(input);");
  syn nta DefaultMappingDefinition RagConnect.defaultStringToShortMapping() = baseDefaultMappingDefinition(
      "String", "short", "return Short.parseShort(input);");
  syn nta DefaultMappingDefinition RagConnect.defaultStringToLongMapping() = baseDefaultMappingDefinition(
      "String", "long", "return Long.parseLong(input);");
  syn nta DefaultMappingDefinition RagConnect.defaultStringToFloatMapping() = baseDefaultMappingDefinition(
      "String", "float", "return Float.parseFloat(input);");
  syn nta DefaultMappingDefinition RagConnect.defaultStringToDoubleMapping() = baseDefaultMappingDefinition(
      "String", "double", "return Double.parseDouble(input);");
  syn nta DefaultMappingDefinition RagConnect.defaultStringToCharMapping() = baseDefaultMappingDefinition(
      "String", "char", "return input.charAt(0);");

  syn nta DefaultMappingDefinition RagConnect.defaultIntToStringMapping() = baseDefaultMappingDefinition(
      "int", "String", "return String.valueOf(input);");
  syn nta DefaultMappingDefinition RagConnect.defaultShortToStringMapping() = baseDefaultMappingDefinition(
      "short", "String", "return String.valueOf(input);");
  syn nta DefaultMappingDefinition RagConnect.defaultLongToStringMapping() = baseDefaultMappingDefinition(
      "long", "String", "return String.valueOf(input);");
  syn nta DefaultMappingDefinition RagConnect.defaultFloatToStringMapping() = baseDefaultMappingDefinition(
      "float", "String", "return String.valueOf(input);");
  syn nta DefaultMappingDefinition RagConnect.defaultDoubleToStringMapping() = baseDefaultMappingDefinition(
      "double", "String", "return String.valueOf(input);");
  syn nta DefaultMappingDefinition RagConnect.defaultCharToStringMapping() = baseDefaultMappingDefinition(
      "char", "String", "return String.valueOf(input);");
}

aspect Mappings {
  // --- effectiveMappings ---
  syn java.util.List<MappingDefinition> EndpointDefinition.effectiveMappings();
  eq ReceiveTokenEndpointDefinition.effectiveMappings() {
    // if there is a first mapping, check if it is suitable.
    //  or if no mappings are specified.
    // then prepend the suitable default mapping
    java.util.List<MappingDefinition> result;
    if (getMappingList().isEmpty() || !hasSuitableEdgeMapping()) {
      result = new java.util.ArrayList();
      result.add(suitableDefaultMapping());
      result.addAll(getMappingList());
    } else {
      result = getMappingList();
    }
    return result;
  }
  eq SendTokenEndpointDefinition.effectiveMappings() {
    // if there is a mapping, check if it is suitable.
    //  or if no mappings are specified.
    // then append the suitable default mapping
    java.util.List<MappingDefinition> result;
    if (getMappingList().isEmpty() || !hasSuitableEdgeMapping()) {
      result = new java.util.ArrayList();
      result.addAll(getMappingList());
      result.add(suitableDefaultMapping());
    } else {
      result = getMappingList();
    }
    return result;
  }

  // --- hasSuitableEdgeMapping ---
  syn boolean TokenEndpointDefinition.hasSuitableEdgeMapping();
  eq ReceiveTokenEndpointDefinition.hasSuitableEdgeMapping() = isSuitableEdgeMapping(getMappingList().get(0));
  eq SendTokenEndpointDefinition.hasSuitableEdgeMapping() = isSuitableEdgeMapping(getMappingList().get(getMappingList().size() - 1));

  // --- isSuitableEdgeMapping(def) ---
  syn boolean TokenEndpointDefinition.isSuitableEdgeMapping(MappingDefinition def);
  eq ReceiveTokenEndpointDefinition.isSuitableEdgeMapping(MappingDefinition def) = def.getFromType().isByteArray();
  eq SendTokenEndpointDefinition.isSuitableEdgeMapping(MappingDefinition def) = def.getToType().isByteArray();

  // --- isPrimitiveType ---
  syn boolean TokenComponent.isPrimitiveType() = effectiveJavaTypeUse().isPrimitiveType();
  syn boolean JavaTypeUse.isPrimitiveType() = false;
  eq SimpleJavaTypeUse.isPrimitiveType() {
    switch(getName()) {
      case "int":
      case "short":
      case "long":
      case "float":
      case "double":
      case "char":
      case "byte": return true;
      default: return false;
    }
  }
  syn boolean MappingDefinitionType.isPrimitiveType() = false;
  eq JavaMappingDefinitionType.isPrimitiveType() = getType().isPrimitiveType();

  // --- isArray ---
  syn boolean MappingDefinitionType.isArray() = false;
  eq JavaArrayMappingDefinitionType.isArray() = true;

  // --- suitableDefaultMapping ---
  syn DefaultMappingDefinition EndpointDefinition.suitableDefaultMapping();
  eq ReceiveTokenEndpointDefinition.suitableDefaultMapping() {
    String typeName = getMappingList().isEmpty() ?
        getToken().effectiveJavaTypeUse().getName() :
        getMappingList().get(0).getFromType().prettyPrint();
    switch(typeName) {
      case "int":
      case "Integer": return ragconnect().defaultBytesToIntMapping();
      case "short":
      case "Short": return ragconnect().defaultBytesToShortMapping();
      case "long":
      case "Long": return ragconnect().defaultBytesToLongMapping();
      case "float":
      case "Float": return ragconnect().defaultBytesToFloatMapping();
      case "double":
      case "Double": return ragconnect().defaultBytesToDoubleMapping();
      case "char":
      case "Character": return ragconnect().defaultBytesToCharMapping();
      case "String": return ragconnect().defaultBytesToStringMapping();
      default: return null;
    }
  }
  eq SendTokenEndpointDefinition.suitableDefaultMapping() {
    String typeName = getMappingList().isEmpty() ?
        getToken().effectiveJavaTypeUse().getName() :
        getMappingList().get(getMappingList().size() - 1).getFromType().prettyPrint();
    switch(typeName) {
      case "int":
      case "Integer": return ragconnect().defaultIntToBytesMapping();
      case "short":
      case "Short": return ragconnect().defaultShortToBytesMapping();
      case "long":
      case "Long": return ragconnect().defaultLongToBytesMapping();
      case "float":
      case "Float": return ragconnect().defaultFloatToBytesMapping();
      case "double":
      case "Double": return ragconnect().defaultDoubleToBytesMapping();
      case "char":
      case "Character": return ragconnect().defaultCharToBytesMapping();
      case "String": return ragconnect().defaultStringToBytesMapping();
      default: return null;
    }
  }
//  eq ReceiveFromRestDefinition.suitableDefaultMapping() {
//    String typeName = getMappingList().isEmpty() ?
//        getToken().getJavaTypeUse().getName() :
//        getMappingList().get(0).getFromType().prettyPrint();
//    switch(typeName) {
//      case "int":
//      case "Integer": return ragconnect().defaultStringToIntMapping();
//      case "short":
//      case "Short": return ragconnect().defaultStringToShortMapping();
//      case "long":
//      case "Long": return ragconnect().defaultStringToLongMapping();
//      case "float":
//      case "Float": return ragconnect().defaultStringToFloatMapping();
//      case "double":
//      case "Double": return ragconnect().defaultStringToDoubleMapping();
//      case "char":
//      case "Character": return ragconnect().defaultStringToCharMapping();
//      default: return null;
//    }
//  }
//  eq SendToRestDefinition.suitableDefaultMapping() {
//    String typeName = getMappingList().isEmpty() ?
//        getToken().getJavaTypeUse().getName() :
//        getMappingList().get(getMappingList().size() - 1).getFromType().prettyPrint();
//    switch(typeName) {
//      case "int":
//      case "Integer": return ragconnect().defaultIntToStringMapping();
//      case "short":
//      case "Short": return ragconnect().defaultShortToStringMapping();
//      case "long":
//      case "Long": return ragconnect().defaultLongToStringMapping();
//      case "float":
//      case "Float": return ragconnect().defaultFloatToStringMapping();
//      case "double":
//      case "Double": return ragconnect().defaultDoubleToStringMapping();
//      case "char":
//      case "Character": return ragconnect().defaultCharToStringMapping();
//      default: return null;
//    }
//  }

  // --- isByteArray ---
  syn boolean MappingDefinitionType.isByteArray() = false;
  eq JavaArrayMappingDefinitionType.isByteArray() = getType().getName().equals("byte");

//  // --- isString ---
//  syn boolean MappingDefinitionType.isString() = false;
//  eq JavaMappingDefinitionType.isString() = getType().getName().equals("String");

  // --- allMappingDefinitions ---
  syn java.util.List<MappingDefinition> RagConnect.allMappingDefinitions() {
    java.util.List<MappingDefinition> result = new java.util.ArrayList<>();
    getMappingDefinitionList().iterator().forEachRemaining(result::add);
    // byte[] conversion
    result.add(defaultBytesToIntMapping());
    result.add(defaultBytesToShortMapping());
    result.add(defaultBytesToLongMapping());
    result.add(defaultBytesToFloatMapping());
    result.add(defaultBytesToDoubleMapping());
    result.add(defaultBytesToCharMapping());
    result.add(defaultBytesToStringMapping());
    result.add(defaultIntToBytesMapping());
    result.add(defaultShortToBytesMapping());
    result.add(defaultLongToBytesMapping());
    result.add(defaultFloatToBytesMapping());
    result.add(defaultDoubleToBytesMapping());
    result.add(defaultCharToBytesMapping());
    result.add(defaultStringToBytesMapping());
//    // string conversion
//    result.add(defaultStringToIntMapping());
//    result.add(defaultStringToShortMapping());
//    result.add(defaultStringToLongMapping());
//    result.add(defaultStringToFloatMapping());
//    result.add(defaultStringToDoubleMapping());
//    result.add(defaultStringToCharMapping());
//    result.add(defaultIntToStringMapping());
//    result.add(defaultShortToStringMapping());
//    result.add(defaultLongToStringMapping());
//    result.add(defaultFloatToStringMapping());
//    result.add(defaultDoubleToStringMapping());
//    result.add(defaultCharToStringMapping());
    return result;
  }
}